Intel ITANIUM ARCHITECTURE - SOFTWARE DEVELOPERS VOLUME 3 REV 2.3, Manual

Page: 779 / 1898

Volume 2, Part 2: MP Coherence and Synchronization 2:531
2.5 Updating Code Images
There are four general techniques for updating code images in order to modify the code
stream of a local or remote processor.
• Self-modifying code or code that modifies its own image.
• Cross-modifying code or code that modifies the image of code running concurrently
on another processor.
Figure 2-7. Lamport’s Algorithm
// The proc_id variable holds a unique, non-zero id for the process that
// attempts access to the critical section. x and y are the synchronization
// variables that indicate who is in the critical section and who is
// attempting entry. ptr_b_1 and ptr_b_id point at the 1’st and id’th
// element of b[].
//
lamport:
ld8 r1 = [proc_id] ;; // r1 = unique process id
start:
st8 [ptr_b_id] = r1 // b[id] = “true”
st8 [x] = r1 // x = process id
mf // MUST fence here!
ld8 r2 = [y] ;;
cmp.ne p1, p0 = 0, r2;; // if (y != 0) then...
(p1) st8 [ptr_b_id] = r0 // ... b[id] = “false”
(p1) br.cond.sptk wait_y // ... wait until y == 0
st8 [y] = r1 // y = process id
mf // MUST fence here!
ld8 r3 = [x] ;;
cmp.eq p1, p0 = r1, r3 ;; // if (x == id) then...
(p1) br.cond.sptk cs_begin // ... enter critical section
st8 [ptr_b_id] = r0 // b[id] = “false”
ld8 r3 = [ptr_b_1] // r3 = &b[1]
mov ar.lc = N-1 ;; // lc = number of processors - 1
wait_b:
ld8 r2 = [r3] ;;
cmp.ne p1, p0 = r1, r2 // if (b[j] != 0) then...
(p1) br.cond.spnt wait_b ;; // ... wait until b[j] == 0
add r3 = 8, r3 // r3 = &b[j+1]
br.cloop.sptk wait_b ;; // loop over b[j] for each j
ld8 r2 = [y] ;;
cmp.ne p1, p0 = r2, r1 ;; // if (y != id) then...
(p1) br.cond.sptk cs_begin // ... enter critical section
wait_y:
ld8 r2 = [y] ;; // wait until y == 0
cmp.ne p1, p2 = 0, r2
(p1) br.cond.spnt wait_y
br start // back to start to try again
cs_begin:
// critical section code goes here...
cs_end:
st8 [y] = r0 // release the lock
st8.rel [ptr_b_id] = r0;; // b[id] = “false”